原创:as3isolib_中文教程_008&007

008就是告诉你怎么在flex中用as3isolib,只要用过flex的人肯定都知道啦，所以姐也不啰嗦了。所以下面重点说007，古往今来，重头戏都是007，比如黄金眼007，大内密探007啦啦啦，不扯远了，原文地址：

http://code.google.com/p/as3isolib/wiki/as3isolib_tutorial_007

下面是翻译内容:

这个教程用到了 Grant Skinner的 GTween 库. 你能在这下载 到这个库的东东

大部分开发者都能找到各种层次的用as3Isolib做的交互式应用，这儿有个例子告诉你怎么用grid和box快速的建立一个简单的交互应用，点击grid上的任何一个cell，box都会朝那个cell运动。

google上的代码有点小问题，所以姐再次很勤奋的倒腾出一个能编译通过的版本，哈哈

以下代码在flashdevelop下编译通过，配置环境:sdk4,flashplayer10

package
{
import as3isolib.core.IIsoDisplayObject;
import as3isolib.display.IsoView;
import as3isolib.display.primitive.IsoBox;
import as3isolib.display.scene.IsoGrid;
import as3isolib.display.scene.IsoScene;
import as3isolib.geom.IsoMath;
import as3isolib.geom.Pt;

import com.gskinner.motion.GTween;

import eDpLib.events.ProxyEvent;

import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;

/**
* …
* @author amyflash.com
*/
public class IsoApplication7 extends Sprite
{
private var box:IIsoDisplayObject;
private var scene:IsoScene;

public function IsoApplication7 ()
{
scene = new IsoScene();

var g:IsoGrid = new IsoGrid();
g.showOrigin = false;
g.addEventListener(MouseEvent.CLICK, grid_mouseHandler);
scene.addChild(g);

box = new IsoBox();
box.setSize(25, 25, 25);
scene.addChild(box);

var view:IsoView = new IsoView();
view.clipContent = false;
view.y = 50;
view.setSize(150, 100);
view.addScene(scene); //以后可以增加更多场景
addChild(view);

scene.render();
}

private var gt:GTween;

private function grid_mouseHandler (evt:ProxyEvent):void
{
var mEvt:MouseEvent = MouseEvent(evt.targetEvent);
var pt:Pt = new Pt(mEvt.localX, mEvt.localY);
IsoMath.screenToIso(pt);

if (gt)
gt.end();

else
{
gt = new GTween();
gt.addEventListener(Event.COMPLETE, gt_completeHandler);
}

gt.target = box;
gt.duration = 0.5;

//gt.setValues({x:pt.x, y:pt.y});//GTween_v2_01版本中用这个
gt.setProperties({x:pt.x, y:pt.y});
gt.play();

if (!hasEventListener(Event.ENTER_FRAME))
this.addEventListener(Event.ENTER_FRAME, enterFrameHandler);
}

private function gt_completeHandler (evt:Event):void
{
this.removeEventListener(Event.ENTER_FRAME, enterFrameHandler);
}

private function enterFrameHandler (evt:Event):void
{
scene.render();
}
}

}